# Author: Benny R.
reset
set terminal svg size 800,600 fixed enhanced font "Verdana"
set encoding iso_8859_1

set style line 1 linetype 1 linewidth 2 linecolor rgb "black"
set style line 2 linetype 1 linewidth 2 linecolor rgb "red"
set style line 3 linetype 1 linewidth 2 linecolor rgb "blue"
set style line 4 linetype 1 linewidth 2 linecolor rgb "dark-green"

set style line 5 linetype 1 linewidth 0 linecolor rgb "gray90"
set style line 6 linetype 1 linewidth 0 linecolor rgb "lemonchiffon"

w (x, a, b) = x * a / sqrt (a**2 + b**2)
h (x, a, b) = x * b / sqrt (a**2 + b**2)
xrange = 55

unset key
set grid front

set xlabel "Bildschirmdiagonale in Zoll"
set xrange [13:xrange]
set xtics 5
set mxtics 5

set ylabel "H\366he und Breite in cm"
set autoscale y
set ytics 5
set mytics 5

set label 1 "Breite"  at 0.65*xrange, 2.54*0.68*xrange center front textcolor rgb "dark-yellow" font "Verdana,40" offset 0, 1
set label 2 "H\366he" at 0.85*xrange, 2.54*0.25*xrange center front textcolor rgb "dark-gray" font "Verdana,40" offset 0, 1

set label 3  "5:4"   at 0.9*xrange, 2.54*w(0.9*xrange, 5.0, 4.0)   left  front textcolor rgb "black"      offset 0.2, -0.5
set label 4  "5:4"   at 0.9*xrange, 2.54*h(0.9*xrange, 5.0, 4.0)   right front textcolor rgb "black"      offset -0.2, 0.5
set label 5  "4:3"   at 0.9*xrange, 2.54*w(0.9*xrange, 4.0, 3.0)   right front textcolor rgb "red"        offset -0.2, 0.5
set label 6  "4:3"   at 0.9*xrange, 2.54*h(0.9*xrange, 4.0, 3.0)   left  front textcolor rgb "red"        offset 0.2, -0.5
set label 7  "16:10" at 0.9*xrange, 2.54*w(0.9*xrange, 16.0, 10.0) left  front textcolor rgb "blue"       offset 0.2, -0.5
set label 8  "16:10" at 0.9*xrange, 2.54*h(0.9*xrange, 16.0, 10.0) right front textcolor rgb "blue"       offset -0.2, 0.5
set label 9  "16:9"  at 0.9*xrange, 2.54*w(0.9*xrange, 16.0, 9.0)  right front textcolor rgb "dark-green" offset -0.2, 0.5
set label 10 "16:9"  at 0.9*xrange, 2.54*h(0.9*xrange, 16.0, 9.0)  left  front textcolor rgb "dark-green" offset 0.2, -0.5

set output "bildschirmgroesse.svg"

plot 2.54*x/sqrt(2) ls 5 with filledcurves x1,\
     2.54*x/sqrt(2) ls 6 with filledcurves x2,\
     2.54*w(x,5.0,4.0) ls 1,\
     2.54*h(x,5.0,4.0) ls 1,\
     2.54*w(x,4.0,3.0) ls 2,\
     2.54*h(x,4.0,3.0) ls 2,\
     2.54*w(x,16.0,10.0) ls 3,\
     2.54*h(x,16.0,10.0) ls 3,\
     2.54*w(x,16.0,9.0) ls 4,\
     2.54*h(x,16.0,9.0) ls 4

set output
set terminal pop
reset