// Données

X = 1:4;
Y = [6, 5, 7, 10];

// régression horizontale
[a, b, sigma] = reglin(Y, X);

// régression verticale
[aa, bb, sigma] = reglin(X, Y);

// points projetés sur la droite

X1 = a*Y + b;
Y1 = aa*X + bb;

// droite de régression horizontale
y1 = 4; x1 = a*y1 + b;
y2 = 10.25; x2 = a*y2 + b;

// droite de régression verticale
xx1 = (y1 - bb)/aa;
xx2 = (y2 - bb)/aa;

// tracé
clf;
couleurs = [get(sdf(), 'color_map') ; 0.75, 0.75, 0.75];
xset('colormap', couleurs);

xsegs([X ; X1], [Y ; Y], 14) // segments horizontaux
h1 = gce();
h1.line_style = 2;

xsegs([X ; X], [Y ; Y1], 14) // segments verticaux
h2 = gce();
h2.thickness = 2;

xpoly([xx1, xx2], [y1, y2]) // droite de régression verticale
h3 = gce();
h3.thickness = 2;
h3.foreground = 2;

xpoly([x1, x2], [y1, y2]) // droite de régression horizontale
h4 = gce();
h4.line_style = 2;
h4.foreground = 2;

plot(X, Y, 'ok') // points
h5 = gce();
h5.children.mark_background = 5;
axe = gca();
axe.data_bounds = [0, 4 ; 5, 10.25];
axe.grid = [33, 33];
axe.tight_limits = 'on';
axe.isoview = 'on';
xtitle(' ', 'x', 'y')