File:Maxwell-coil-field-3D.png
Summary
| Description |
English: 3D plot of the absolute value of the magnetic field B of a Maxwell coil consisting of three thin circular coils arranged to create a maximally uniform field in the center. The inner central coil has radius R and current I. The two outer coils have radii , axial distance and carry the current 49/64I. The central coil radius R is set to 1. The B-field is given in units of the central field . |
| Date | |
| Source | Own work Category:PNG created with Mathematica#Maxwell-coil-field-3D.png |
| Author | Geek3 |
Mathematica Source Code
Bx[x_, z_, R_] =
If[Abs[x/R] < 10^-5, 0, z/(2 Pi x) (\[Beta] = (x + R)^2 + z^2;
m = 4 x*R/\[Beta];
1/Sqrt[\[Beta]] ((R^2 + x^2 + z^2)/((R - x)^2 + z^2) EllipticE[
m] - EllipticK[m]))];
Bz[x_, z_, R_] = 1/(2 Pi) (\[Beta] = (x + R)^2 + z^2;
m = 4 x*R/\[Beta];
1/Sqrt[\[Beta]] ((R^2 - x^2 - z^2)/((R - x)^2 + z^2) EllipticE[
m] + EllipticK[m]));
B[x_, z_, R_] = {Bx[x, z, R], Bz[x, z, R]};
ColorFunc[x_] =
Blend[{{0, Hue[0.65, 0.6, 1]}, {1/4, Hue[1/3, 0.7, 0.8]}, {1/2,
Hue[1/6, 0.9, 0.8]}, {1, RGBColor[0.95, 0.2, 0.2]}}, x];
R = 1;
plot = Plot3D[
R*16/15 Norm[
B[x, z, R] + 49/64 B[x, z - R*Sqrt[3/7], R Sqrt[4/7]] +
49/64 B[x, z + R*Sqrt[3/7], R Sqrt[4/7]]],
{x, -2, 2}, {z, -2, 2}, PlotRange -> {0, 2},
BoxRatios -> {4, 4, 2},
AxesLabel -> {"\[Rho]", "z", "\!\(\*FractionBox[\"B\",
RowBox[{\"B\",
RowBox[{\"(\", \"0\", \")\"}]}]]\)"},
AxesEdge -> {{-1, -1}, {1, -1}, {1, 1}}, PlotPoints -> 301,
MaxRecursion -> 2, Method -> {Refinement -> {ControlValue -> 0.05}},
ImageSize -> 800, ClippingStyle -> None,
Mesh -> {7, 9, Range[0, 3/2, 1/2]},
MeshFunctions -> {#1 &, #2 &, #3 &},
MeshStyle -> {Black, Black, {LightGray, Thickness[0.002]}},
ColorFunction -> (Directive[SurfaceColor@Darker[ColorFunc[#3], 0.2],
Glow@Darker[ColorFunc[#3], 0.8], Specularity[0.3, 40]] &),
BaseStyle -> {FontSize -> 20}, ViewPoint -> {4, -10, 6}]
SetDirectory[NotebookDirectory[]];
Export["Maxwell-coil-field-3D.png", plot, ImageResolution -> 300];
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
