grafico di VoN=f(IoN) di un convertitore boost. Questa figura è stata fatta usando gnuplot 4.0 con il sorgente seguente (rilasciato come materiale di pubblico dominio):

# This file is used to plot the domains of continuous and
# discontinuous operation of a boost converter

# graph configuration
set terminal svg enhanced fname "Times" fsize 18
set output "boost_continuo_discontinuo.svg"

set key off
set mxtics 
set mytics 
set grid xtics ytics
set ylabel "Tensione normalizzata"
set xlabel "Corrente normalizzata"
set format y '%0.1f'
set format x "%0.2f" 
set samples 1500

# labels displayed on the graph
set label 1 'modo discontinuo' at 0.075,1.6  left
set label 2 'modo continuo' at 0.175,3.5 center
set label 3 'D=0.0' at 0.24,0.8 right
set label 4 'D=0.2' at 0.24,1.45 right
set label 5 'D=0.4' at 0.24,1.9 right
set label 6 'D=0.6' at 0.24,2.7 right
set label 7 'D=0.8' at 0.24,5.2 right

# normalized voltage=g(normalized current)
fdisc(x,D) = D**2/(2*x)+1
fcont(x,D) = 1/(1-D)
g(x,D) = fdisc(x,D)<=fcont(x,D)?fcont(x,D):fdisc(x,D)
x1(t) = t

#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)/2*t
my_y(t) = 1/(1-t)

# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:6] t,g(t,0) lw 2, \
        t,g(t,0.2) lw 2, \
        t,g(t,0.4) lw 2, \
        t,g(t,0.6) lw 2, \
        t,g(t,0.8) lw 2, \
        my_x(t),my_y(t) lw 2