/*
 ================================================
 Animation of V-shaped guide patterns in action
 ------------------------------------------------
 Created by Søren Peo Pedersen - see my user page
 at http://da.wikipedia.org/wiki/Bruger:Peo
 ================================================
 */

 #declare MagnetFont="arialbd.ttf" // Font for the nomenclature on magnets
 #declare NorthLtr="N";  // Letter to indicate north pole
 #declare SouthLtr="S";  // Letter to indicate south pole

 #declare TrkPhase=-1+clock;  // Compute phase count from clock system variable
 #declare BubblePosX=1.6*TrkPhase;  // Compute X and Z position of the
 #declare BubblePosZ=cos(2*pi*TrkPhase)*-.35; // moving bubbles
 
 box {<-4,-.3,-4>,<4,.3,4>  // The orthomagnetic sheet
   pigment {
     object {
       merge {
         // A "chain" of bubbles moving according to computed position:
         cylinder {<BubblePosX-1.6,-1,2.5+BubblePosZ>,<BubblePosX-1.6,1,2.5+BubblePosZ>,.3}
         cylinder {<BubblePosX,-1,2.5+BubblePosZ>,<BubblePosX,1,2.5+BubblePosZ>,.3}
         cylinder {<BubblePosX+1.6,-1,2.5+BubblePosZ>,<BubblePosX+1.6,1,2.5+BubblePosZ>,.3}
         cylinder {<BubblePosX+3.2,-1,2.5+BubblePosZ>,<BubblePosX+3.2,1,2.5+BubblePosZ>,.3}
         }
       pigment {color rgb <1,1,1>}  // Simple colors to indi-
       pigment {color rgb <1,0,0>}  // cate the magnetization
       }
     }
   finish {ambient .5}
   }

 #local Col=0;   // Loop to place a series of V-shaped guides on the sheet
 #while (Col<4)
   merge {
     sphere {<0,.3,0>,.03}                 // "V"-shapes are made with lots of
     cylinder {<0,.3,0>,<-1,.3,0>,.03}     // spheres and cylinders to provide
     sphere {<-1,.3,0>,.03}                // smoothly rounded corners and ed-
     cylinder {<-1,.3,0>,<-1,.3,.2>,.03}   // ges
     sphere {<-1,.3,.2>,.03}
     cylinder {<-1,.3,.2>,<-.2,.3,.2>,.03}
     sphere {<-.2,.3,.2>,.03}
     cylinder {<-.2,.3,.2>,<-.2,.3,1>,.03}
     sphere {<-.2,.3,1>,.03}
     cylinder {<-.2,.3,1>,<0,.3,1>,.03}
     sphere {<0,.3,1>,.03}
     cylinder {<0,.3,0>,<0,.3,1>,.03}
     box {<-1,.3,0>,<0,.33,.2>}
     box {<-.2,.3,.2>,<0,.33,1>}
     rotate <0,45,0>
     pigment {
       gradient z        // Apply a gradient of colors
       color_map {       // to indicate magnetization
         [0 color rgb <1,.25,.25>]
         [.48 color rgb .5]
         [.52 color rgb .5]
         [1 color rgb 1]    
         }
       translate -.5
       scale 1.55
       rotate <0,-360*TrkPhase+180,0>  // Gradient turns once per phase count
       translate <0,0,.5>
       }
     finish {ambient .5 phong 1}
     translate <1.6*Col-3.2,0,2>
     }
   #local Col=Col+1;
 #end

 merge {         // The black arrow that indicates the direction
   difference {  // of the collective field from the driving coils
     box {<0,-.001,-1>,<1,.001,0>
       rotate <0,45,0> scale <1,1,3> translate <0,0,.7>}
     plane {<0,0,1>,.1}
     }
   box {<-.05,-.001,-.7>,<.05,.001,.1>}
   pigment {color rgb 0}
   rotate <0,-360*TrkPhase,0> // Turns COUNTERCLOCKWISE once per phase count
   translate <0,0,5.2>
   }
 
 // Render the north pole nomenclature that follows the rotating arrow:
 #declare Nletter=text {ttf MagnetFont,NorthLtr,0,.001 scale .5 rotate <90,0,0>}
 #object {Nletter
   translate <
     (min_extent(Nletter).x-max_extent(Nletter).x)/2-sin(-TrkPhase*2*pi)*.95
     0,
     (min_extent(Nletter).z-max_extent(Nletter).z)/2-cos(-TrkPhase*2*pi)*.95+5.2>
     }
 
 // Render the south pole nomenclature that follows the rotating arrow:
 #declare Sletter=text {ttf MagnetFont,SouthLtr,0,.001 scale .5 rotate <90,0,0>}
 #object {Sletter
   translate <
     (min_extent(Sletter).x-max_extent(Sletter).x)/2+sin(-TrkPhase*2*pi)*.95
     0,
     (min_extent(Sletter).z-max_extent(Sletter).z)/2+cos(-TrkPhase*2*pi)*.95+5.2>
     }
 
 background {color rgb 1} // White background
 
 camera { // Look at the scenario   
   location <0,4,3.7> // from this vantage point,
   look_at <0,0,3.7>  // looking towards this point.
   up <0,4/3,0> right <1,0,0> // Force 4:3 "portrait" aspect.
   }
 
 light_source {     // Illumination
   <-100,150,-120>
   color rgb 1
   }