File:RollingVsInertia.gif
Summary
| Description |
English: Cylinders with the same mass but different moments of inertia will roll down a flat surface at different accelerations, as they have to "convert" different amounts of potential energy into kinetic energy to achieve a given angular velocity. |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1225050271384002561 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 11.0 code
s1[t_] := R1 \[Phi]1[t];
x1[t_] := x10 + s1[t] Cos[\[Alpha]] + R1 Sin[\[Alpha]];
y10 = Abs[x10] Tan[\[Alpha]];
y1[t_] := y10 - s1[t] Sin[\[Alpha]] + R1 Cos[\[Alpha]];
T1[t_] := 1/2 m1 (D[x1[t], t]^2 + D[y1[t], t]^2) + 1/2 I1 (D[\[Phi]1[t], t])^2;
V1[t_] := m1 g y1[t];
L = FullSimplify[T1[t] - V1[t]]
eq1 = FullSimplify[D[D[L, \[Phi]1'[t]], t] - D[L, \[Phi]1[t]]]
m1 = 1; R1 = 1; g = 1; \[Alpha] = \[Pi]/6; x10 = -20;
sol = Table[
NDSolve[{(eq1 == 0) /. {I1 -> j}, \[Phi]1[0] == 0, \[Phi]1'[0] == 1}, {\[Phi]1[t]}, {t, 0, 20}], {j, 0, 5}];
dim = Dimensions[sol][[1]];
\[CapitalDelta] = 2;
p1 = Table[ Legended[Graphics3D[{
Gray, Polygon[{{0, \[CapitalDelta], 0}, {1.2*x10, \[CapitalDelta], 1.2 y10}, {1.2*x10, (dim + 1) \[CapitalDelta], 1.2 y10}, {0, (dim + 1) \[CapitalDelta], 0}}], Table[{Hue[j/dim], Cylinder[({{x1[t], \[CapitalDelta] j, y1[t]}, {x1[t], \[CapitalDelta] (j + 1), y1[t]}} /. sol[[j]]) /. {t -> \[Tau]}, R1]}, {j, 1, dim}]}, Boxed -> False],
PointLegend[Table[Hue[j/dim], {j, 1, dim}] , Table[StringJoin["m=\!\(\*SubscriptBox[\(m\), \(0\)]\) I=", ToString[j], "\!\(\*SubscriptBox[\(I\), \(0\)]\)"], {j, 1, dim}], LegendMarkerSize -> 20, LabelStyle -> {FontFamily -> "Times"}] ]
, {\[Tau], 0, 7.3, 0.1}];
ListAnimate[p1]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
