File:Ewald-Oseen theorem.gif
Summary
| Description |
English: When light (green arrow) hits a bunch of small obstacles it is scattered around in a pattern that gets more complex the more obstacles are there. Until they become too dense, and more and more light gets scattered forward due to interference between the scattered waves.. |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1559456274101714945 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 13.1 code
\[Lambda] = 1.; c = 1.;
k0 = (2 \[Pi])/\[Lambda]; \[Omega] = c k0;
\[Alpha] = 4/(k0^2 I); \[Sigma] = (k0^3 Norm[\[Alpha]]^2)/4;
G[r_] := N[I/4 HankelH1[0, k0 Norm[r] ]];
source[{x_, y_}] := E^(I k0 x)*E^(-(y^2/(2*(15)^2)));
Lx = 10; Ly = 20; ndipolesmax = 100;
R = 3*Ly(*6000*);
dipoles = RandomVariate[UniformDistribution[{{-Lx/2, Lx/2}, {-Ly/2, Ly/2}}], {ndipolesmax}];
frames = Table[
E0 = Table[source[dipoles[[j]]], {j, 1, ndipoles}];
M = Table[ If[k == j, 1, \[Alpha] k0^2 G[dipoles[[j]] - dipoles[[k]] ] ] , {j, 1, ndipoles}, {k, 1, ndipoles}];
iM = Inverse[M];
Escattered = iM . E0;
Etot[x_, y_] :=(*source[{x, y}]+*) \[Alpha] k0^2 Sum[ G[{x, y} - dipoles[[j]] ] Escattered[[j]], {j, 1, ndipoles}];
scatteredfield = Table[{\[Theta], Abs[\[Alpha] k0^2 Sum[ G[{R*Cos[\[Theta]], R*Sin[\[Theta]]} - dipoles[[j]] ] Escattered[[j]], {j, 1, ndipoles}]]^2}, {\[Theta], 0, 2 \[Pi], (2 \[Pi])/(5*360)}];
Show[
ListPolarPlot[(#[[2]]/Max[scatteredfield[[All, 2]]] + 1.05) & /@ scatteredfield, Joined -> True, Axes -> False, PlotStyle -> Purple],
DensityPlot[ Abs[Etot[3 Ly x, 3 Ly y]]^2, {x, y} \[Element] Disk[], PlotPoints -> 50, ColorFunction -> "AvocadoColors", PlotRange -> {0, 1}, Frame -> False],
Graphics[{Orange, PointSize -> 0.005, Point[dipoles[[1 ;; ndipoles]]/(3 Ly)], LightGray, Thick, Circle[], Green, Thick, Arrow[{{-1.4, 0}, {-1, 0}}]}], PlotRange -> {{-2.1, 2.1}, {-2.1, 2.1}}]
, {ndipoles, 1, ndipolesmax}];
ListAnimate[ Join[Join[Flatten@Table[ Table[frames[[j]], Ceiling[10/(1 + E^(j - 5))]], {j, 1, ndipolesmax}]], Table[frames[[-1]], 10]] ]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
