File:Coriolis.gif
Summary
| Description |
English: If your frame of reference is rotating, objects that are in fact moving in a straight line looks to you like they are bending sideways, like there was a lateral force acting on them (Coriolis force). |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1245346304454209536 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code
\[Omega] = \[Pi]/2;
\[CapitalDelta] = 0.01;
sphr[t_] := Piecewise[{{0, t < 0.5}, {(t - 0.5)/Sqrt[2], 0.5 < t < 1.5}, {1/Sqrt[2], t >= 1.5}}];
landscape = {White, Table[Sphere[{RandomReal[{-4, 4}], RandomReal[{-4, 4}], 0.05}, 0.05], {40}]};
p0 = Table[
GraphicsRow[{
Graphics3D[{
Purple, Table[Sphere[{sphr[\[Tau]], sphr[\[Tau]], 0.11}, 0.02], {\[Tau], 0.5, t, \[CapitalDelta]}], Sphere[{sphr[t], sphr[t], 0.2}, 0.1],
landscape,
Lighter@Gray, Cylinder[{{0, 0, 0}, {0, 0, 0.1}}, 1],
Darker@Green, Cylinder[{{0, 0, 0}, {0, 0, -0.1}}, 10],
Black, Thickness[0.009], Thick, Sphere[{0, 0, 0.1}, 0.05],
Line[{{-Cos[\[Omega] t], -Sin[\[Omega] t], 0.1}, {Cos[\[Omega] t], Sin[\[Omega] t], 0.1}}],
Line[{{-Cos[\[Omega] t + \[Pi]/2], -Sin[\[Omega] t + \[Pi]/2], 0.1}, {Cos[\[Omega] t + \[Pi]/2], Sin[\[Omega] t + \[Pi]/2], 0.1}}]
}, Lighting -> "Neutral",
ViewVector -> {{3, 0, 1.5}, {0, 0, 0}}, ViewVertical -> {0, 0, 1}, ViewAngle -> 50*Degree, Boxed -> False, Background -> Black]
,
Graphics3D[{
Purple, Table[Sphere[{sphr[\[Tau]]*Sqrt[2] Cos[\[Omega] (t - \[Tau]) + \[Pi]/4], sphr[\[Tau]]*Sqrt[2] Sin[\[Omega] (t - \[Tau]) + \[Pi]/4], 0.11}, 0.02], {\[Tau], 0, t, \[CapitalDelta]}],
Sphere[{sphr[t], sphr[t], 0.2}, 0.1],
landscape,
Lighter@Gray, Cylinder[{{0, 0, 0}, {0, 0, 0.1}}, 1],
Darker@Green, Cylinder[{{0, 0, 0}, {0, 0, -0.1}}, 10],
Black, Thickness[0.009], Sphere[{0, 0, 0.1}, 0.05],
Line[{{-Cos[\[Omega] t], -Sin[\[Omega] t], 0.11}, {Cos[\[Omega] t], Sin[\[Omega] t], 0.11}}],
Line[{{-Cos[\[Omega] t + \[Pi]/2], -Sin[\[Omega] t + \[Pi]/2], 0.1}, {Cos[\[Omega] t + \[Pi]/2], Sin[\[Omega] t + \[Pi]/2], 0.1}}]
}, Lighting -> "Neutral", ViewVector -> {{3 Cos[\[Omega] t], 3 Sin[\[Omega] t], 1.5}, {0, 0, 0}}, ViewVertical -> {0, 0, 1}, ViewAngle -> 50*Degree, Boxed -> False, Background -> Black]
}]
, {t, 0, 1.5, 1/20}];
ListAnimate[p0]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
