#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['01.01.1945':'31.12.1989']
set xtics '01.01.1100', 60 * 60 * 24 * 365.25 * 10
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5
set format x '%Y'     # Beschriftungsformat JJJJ
set xtics nomirror    # Nur unten Skalieren


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [0:]
set ytics 100000
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format      y  "%'.0f"  # Ausgabeformat
set mytics      5
set ytics nomirror


# Bereiche/Format/etc zweite Y-Achse
set y2label 'Wachstum in Prozent'
set y2range [-20:20]
set y2tics 5
set format      y2  "%'.0f"  # Ausgabeformat
set my2tics      5


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot \
  './Einwohnerentwicklung_von_Leipzig.cvs'\
    using 1:($2) axes x1y1 with linespoints lc 'dark-blue'  lt 1 lw 2 pt 7 ps 0.5,\
  './Einwohnerentwicklung_von_Leipzig.cvs'\
    using 1:($3) axes x1y2 with linespoints lc 'dark-green' lt 1 lw 1 pt 7 ps 0.3


# In der Dateibeschreibung von [[File:Einwohnerentwicklung_von_Leipzig.svg]] 
# sind die zum Erstellen dieser Grafik notwenigen Daten eingestellt. 
# Bitte aus den Daten die Datei 'Einwohnerentwicklung_von_Leipzig.cvs'
# erzeugen und in gleiche Verz. wie diese GnuPlot-Quelle ablegen.