I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue

• ListOfCriticalPoints : (- 0.7558074500261052 %i) - 0.7558074500261052, 0.2793534499540583 %i - 0.5310341598343944, 0.2793534499540583 - 0.5310341598343943 %i, 0.3674881599064412 %i + 0.3674881599064413 with multiplicities= [1, 1, 1, 1]
• finite fixed points : [(- 0.8 %i) - 0.8, 0.0] with stability: [0.6384000000000008, 1.0]
• distance to fixed points after iLength:30000 forward iterations:
  • d1:GiveDistance(first(Orbit1),fixed[1]) = 0.0624977035289329
  • d2:GiveDistance(first(Orbit2),fixed[2]) = 0.6000296900256318
  • d3:GiveDistance(first(Orbit3),fixed[2]) = 0.6000296900256316
  • d4:GiveDistance(first(Orbit4),fixed[2]) = 0.5197067397512218

batch file for Maxima CAS use : - save as p.mac - run Maxima - batch ("p.mac")

kill(all);
remvalue(all);


/*------------- functions definitions ---------*/

/* function */
f(z):=z^5 +(0.8+0.8*%i)*z^4 + z;


/* multiplier */
define(multiplier(z), diff(f(z),z,1));


stability(z):=
block(
	[s],
	s:multiplier(z),
	s: rectform(s),
	s: float(s),
	s: cabs(s),
	return(s)
)$




GiveListOfCriticalPoints(fun):=
block(
  [d,s],
  /* derivative */
  d:diff(fun,z,1),
  /* critical points z: d=0 */
  s:solve(d=0,z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  /* convert to form x+y*%i */
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



/* f(z) is used as a global function
   I do not know how to put it as a argument */

GiveOrbit(z0,OrbitLength):=
block(
 [z,Orbit],
 z:z0,
 Orbit:[z], 
 for i:1 thru OrbitLength step 1 do
        ( z:expand(f(z)),
          Orbit:endcons(z ,Orbit)
          ),
   
 return(Orbit) 

)$

/* find fixed points  returns a list */
GiveFixedPoints():= block
(
  [s],
  s:solve(f(z)=z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



/* 
converts complex number z = x*y*%i 
to the list in a draw format:  
[x,y] 
*/
d(z):=[float(realpart(z)), float(imagpart(z))]$

ToPoint(z):= points([d(z)])$

/* give Draw List from one point*/
dl(z):=[d(z)]$

ToPoints(myList):= points(map(d,myList))$

GiveDistance(z1,z2):= cabs(z1-z2)$



compile(all);

/* ------------  */

iLength:30000;


ListOfCriticalPoints:GiveListOfCriticalPoints(f(z))$
multiplicities;
ListOfCriticalPoints;



fixed :GiveFixedPoints();


stability_list : map(stability, fixed);




Orbit1: GiveOrbit(ListOfCriticalPoints[1],iLength)$
Orbit2: GiveOrbit(ListOfCriticalPoints[2],iLength)$
Orbit3: GiveOrbit(ListOfCriticalPoints[3],iLength)$
Orbit4: GiveOrbit(ListOfCriticalPoints[4],iLength)$

d1: GiveDistance( first(Orbit1), fixed[1]);
d2: GiveDistance( first(Orbit2), fixed[2]);
d3: GiveDistance( first(Orbit3), fixed[2]);
d4: GiveDistance( first(Orbit4), fixed[2]);


/* fixed: ToPoints(fixed)$ */
f1: ToPoint(fixed[1]);
f2: ToPoint(fixed[2]);


Orbit1 : ToPoints(Orbit1)$
Orbit2 : ToPoints(Orbit2)$
Orbit3 : ToPoints(Orbit3)$
Orbit4 : ToPoints(Orbit4)$

cr1: ToPoint(ListOfCriticalPoints[1])$
cr2: ToPoint(ListOfCriticalPoints[2])$
cr3: ToPoint(ListOfCriticalPoints[3])$
cr4: ToPoint(ListOfCriticalPoints[4])$


/*-----------------------------------------------------------------------*/
load(draw); /* ( interface to gnuplot ) by Mario Rodriguez Riotorto http://www.telefonica.net/web2/biomates */

draw2d(
    title = "All  critical orbits for f(z)=z^5 +(0.8+0.8*i)*z^4 + z",
    terminal  = png,
     user_preamble = "set size square", /* 360/26=13.85  ; 360/(2*26)=6,923 */
    file_name = concat("~/Dokumenty/julia_mse/maxima/1/", string(iLength)),
    dimensions  = [1000, 1000],   /* Since Maxima 5.23, pic_width and pic_height are deprecated. */
    
    yrange = [-1.0,1.0],
    xrange = [-1.0,1.0],
    xlabel     = "z.re ",
    ylabel     = "z.im",
    
    point_type    = filled_circle,
    points_joined = false,
    
    
    
    color             = red,
    point_size    = 0.7,
    points_joined = true,
    key=" critical orbit 1",
    Orbit1,
    point_size    = 1.2,
    key= "",
    points_joined = false,
    cr1,
    
    color             = magenta,
    point_size    = 0.7,
    points_joined = true,
    key=" critical orbit 2",
    Orbit2,
    point_size    = 1.4,
    key = "",
    points_joined = false,
    cr2,
    
    color             = grey,
    point_size    = 0.7,
    points_joined = true,
    key=" critical orbit 3",
    Orbit3,
    point_size    = 1.4,
    key= "",
    points_joined = false,
    cr3,
    
    
    color             = purple,
    point_size    = 0.7,
    points_joined = true,
    key=" critical orbit 4",
    Orbit4,
    point_size    = 1.4,
    key= "",
    points_joined = false,
    cr4,
    
    
   
    

    key= "attracting fixed point",
    color           = green,
    f1,	

    key= "parabolic fixed point",
    color           = black,
    f2

 );

1. ↑ math.stackexchange question: whats-the-difference-between-a-total-basin-of-attraction-and-an-immediate-basin