File:PlotDiscriminantsOfComplexCubicFields.svg
Summary
| Description |
English: Plot of the number of complex cubic fields of bounded discriminant up to 106, and the asymptotic distribution. Black line is the first order term of the asymptotic, green line includes the second order term, and blue crosses are the exact counts. Data by Michel Olivier available at . Asymptotics from Bhargava–Shankar–Tsimerman, "On the Davenport–Heilbronn theorem and second order terms", arXiv:1005.0672. |
| Date | |
| Source | Own work |
| Author | RobHar |
| SVG development | |
| Source code |
set terminal svg enhanced fname "Helvetica" fsize 20
set output "cubiccomplex.svg"
#Axes
set size square #make the graph square
set logscale #loglog plot
set xrange [ 100 : 1000000 ] #adjust axis range
set yrange [ 1 : 200000 ]
set xlabel "Bound on Discriminant"
set ylabel "Complex Cubic Fields"
set xlabel 0.0, 0.5 #adjust positioning of axis label
set ylabel -2.1, 0.0
#tics
set format "@{10}&{m}^{%L}" #adjust format of tic labels
set xtics offset 1.0,0.45 nomirror #adjust placement of tic labels, and nomirror tics
set ytics offset 3.0,0.0 nomirror
set mxtics 10 #set number of minor tics
set mytics 10
set grid xtics ytics lt rgb "gray" lw 1 #set grid
set style line 1 lt 3 pt 1 ps 0.9 #set marker style to blue cross, adjust size
set style line 2 lt -1 lw 1 #set marker style to black line
set style line 3 lt 2 lw 1 #set marker style to green thick line
f(x) = 0.207976843145176*x - 0.255798375633611*(x**(0.83333333333333333))
g(x) = 0.207976843145176*x
plot "cubiccomplexdata" index 0 using 1:2 notitle with points linestyle 1 ,\
f(x) notitle with lines linestyle 3 ,\
g(x) notitle with lines linestyle 2
|
Licensing
 |
I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law. |
