set style line 1 lc rgb "#ff8000" lw 3          # f
set style line 2 lc rgb "#ff0000" lw 3          # g
set style line 3 lc rgb "#a00000" lw 3          # f/g
set style line 4 lc rgb "#0060ff" lw 1.5        # f'
set style line 5 lc rgb "#0000ff" lw 1.5        # g'
set style line 8 lt 0 lc rgb "#000000"          # major grid
set style line 9 lt 0 lc rgb "#e0e0e0"          # minor grid

set title "Continuous completion of f(x)/g(x) by l'Hopital's rule"
set xlabel "x" 
set ylabel "y" 
set xrange [-6.5:6.5]
set yrange [-2.1:2.1]

set xtics 4
set ytics 1
set mxtics 4
set mytics 2
set grid xtics ytics mxtics mytics ls 8 , ls 9

  plot sin(x)          with lines ls 1 title "f(x) = sin(x)"
replot -0.5*x          with lines ls 2 title "g(x) = -0.5x "
replot -sin(x)/(0.5*x) with lines ls 3 title "f(x)/g(x)             "
replot cos(x)          with lines ls 4 title "f'(x)             "
replot -0.5            with lines ls 5 title "g'(x)             "

set label at 0,-2 point pt 7 lc rgb "#a00000" pointsize 1.5 front
set label at 0,-2 point pt 7 lc rgb "#8080ff" pointsize 1.0 front
set label "defined as f'(0)/g'(0)" at 1.02,-2.05
set arrow from 1,-2.05 to 0.2,-2.01 filled

pause -1