(GPLed) pov file:

#include "colors.inc"

global_settings { ambient_light rgb <10,10,10> }

camera {
	location <100, 100, 100>
	look_at <3,1,3>
	angle 4
}


#declare radiantvertex = union{
cylinder{0, <0,0,1>, .02 pigment {colour White} }
cylinder{0, <0,1,0>, .02 pigment {colour White} }
cylinder{0, <1,0,0>, .02 pigment {colour White} }
}

#declare cubo = union
{
object{radiantvertex}
object{radiantvertex rotate x*180 translate y+z}
object{radiantvertex rotate y*180 translate x+z}
object{radiantvertex rotate z*180 translate x+y}
box { 0, 1 }
}

#declare TNUM = 12;
#declare TRANSP = .5;

#declare LAYERS = 2;
#declare COLS = 6;
#declare ROWS = 5;

//Mapping: F->0 I->1 L->2 N->3 P->4 T->5
//         U->6 V->7 W->8 X->9 Y->10 Z->11
#declare cubes = array[LAYERS][ROWS][COLS]
{
 {
  {5,5,5,7,7,7},
  {6,5,11,11,0,7},
  {6,5,11,0,0,7},
  {6,11,11,2,0,0},
  {2,2,2,2,4,4}
 },
 {
  {1,1,1,1,1,10},
  {6,9,8,8,10,10},
  {9,9,9,8,8,10},
  {6,9,3,3,8,10},
  {3,3,3,4,4,4}
 }
}


#declare cube_cols = array[TNUM]
{
< 226, 246, 0>,//, TRANSP>, 
< 29, 26, 216>,//, TRANSP>, 
< 255, 93, 223>,//, TRANSP>, 
< 3, 0, 255>,//, TRANSP>,
< 0, 225, 0>,//, TRANSP>,
< 0, 255, 236>,//, TRANSP>,
< 255, 0, 204>,//, TRANSP>,
< 0, 180, 165>,//, TRANSP>,
< 144, 238, 144>,//, TRANSP>,
< 255, 0, 3>,//, TRANSP>,
< 52, 6, 179>,//, TRANSP>,
< 179, 178, 6>,//, TRANSP>
}

#declare order = array[TNUM]			//Which pieces show first?
{5, 3, 7, 10, 11, 0, 1, 2, 8, 6, 9, 4}

#declare lidx = 0;

#while (lidx < LAYERS)
	#declare ridx = 0;
	#while (ridx < ROWS)
		#declare cidx = 0;
		#while (cidx < COLS)

			#if (order[cubes[lidx][ridx][cidx]] < clock)
				object{cubo pigment {color rgbt cube_cols[cubes[lidx][ridx][cidx]]/255}
						translate y*lidx+x*ridx+z*cidx}
			#end
		#declare cidx = cidx +1;
		#end
	#declare ridx = ridx +1;
	#end
#declare lidx = lidx +1;
#end

(GPLed) ini file:

; POV-Ray animation ini file
Antialias=Off
Antialias_Threshold=0.1
Antialias_Depth=2

Input_File_Name=polim.pov

Initial_Frame=1
Final_Frame=13
Initial_Clock=1
Final_Clock=13

Cyclic_Animation=on
Pause_when_Done=off

I, the copyright holder of this work, hereby publish it under the following licenses:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Category:License migration redundant#Pentominos%202x5x6.pngCategory:GFDL#Pentominos%202x5x6.png

	This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
	You are free: to share – to copy, distribute and transmit the work to remix – to adapt the work Under the following conditions: attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use. share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
	This licensing tag was added to this file as part of the GFDL licensing update.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Category:CC-BY-SA-3.0-migrated#Pentominos%202x5x6.png

You may select the license of your choice.