Summary

Licensing

I, the copyright holder of this work, hereby publish it under the following license:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
	You are free: to share – to copy, distribute and transmit the work to remix – to adapt the work Under the following conditions: attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use. share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
	This licensing tag was added to this file as part of the GFDL licensing update.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Category:CC-BY-SA-3.0-migrated#Orthomagnetic%20sheet%20for%20bubble%20memory.pngCategory:License migration completed#Orthomagnetic%20sheet%20for%20bubble%20memory.pngCategory:GFDL#Orthomagnetic%20sheet%20for%20bubble%20memory.png

Code

Below is the scene description for the above image, for rendering with the Persistence of Vision Raytracer:

/*
================================================
Orthomagnetic sheet for magnetic bubble memories
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

#declare MagnetFont="arialbd.ttf" // Font for the nomenclature on magnets
#declare NorthLtr="N";  // Letter to indicate north pole
#declare SouthLtr="S";  // Letter to indicate south pole

#declare MagLayerUp=pigment { // Gradient that has
  gradient y                  // white south pole
  color_map {                 // "side" pointing up
    [0.0 color rgb <1,0,0>]   // and red north pole
    [1.0 color rgb <1,1,1>]   // pointing down
    }
  scale .000602
  translate -.000301
  }

#declare MagLayerDn=pigment { // Gradient that has
  gradient y                  // red north pole
  color_map {                 // "side" pointing up
    [0.0 color rgb <1,1,1>]   // and white south
    [1.0 color rgb <1,0,0>]   // pole pointing down
    }
  scale .000602
  translate -.000301
  }

#declare PolLayerUp=pigment { // Like MagLayerUp, but
  object {                    // with "S'es" to indicate
    union {                   // magnetic polarity
      text {ttf MagnetFont,SouthLtr,1,0 scale 1.3 rotate <90,0,0> translate <1,1,0>}
      text {ttf MagnetFont,SouthLtr,1,0 scale 1.3 rotate <90,0,0> translate <1.3,1,-3.1>}
      }
    pigment {MagLayerUp}
    pigment {color rgb <1,0,0>}
    }
  }

#declare PolLayerDn=pigment { // Like MagLayerDn, but
  object {                    // with "N's" to indicate
    union {                   // magnetic polarity
      text {ttf MagnetFont,NorthLtr,1,0 scale 1.3 rotate <90,0,0> translate <-2,1,-1.2>}
      text {ttf MagnetFont,NorthLtr,1,0 scale 1.3 rotate <90,0,0> translate <3,1,-3.7>}
      text {ttf MagnetFont,NorthLtr,1,0 scale 1.3 rotate <90,0,0> translate <2.6,1,-1.2>}
      }
    pigment {MagLayerDn}
    pigment {color rgb <1,1,1>}
    }
  }

box {<-4,-.3,-4>,<4,.3,4>   // The orthomagnetic slab
  pigment {
    bumps           // "Bumps" is the pattern that the
    pigment_map {   // domains' polarities form
      [0.0 PolLayerUp]
      [0.5 PolLayerUp]
      [0.5 PolLayerDn]
      [1.0 PolLayerDn]
      }
    scale <1,1000,1>  // "stretch" so the boundaries look more or
    }                 // less orthogonal with the plate's surface
  finish {ambient .5}
  }

background {color rgb 1}  // White backdrop

camera {              // See the whole scenario
  location <5,6,-7>     // from this point,
  look_at <-.4,-2.1,0>  // looking towards this point.
  angle 60  // "Fine-tune" field-of-view to fit the motif
  }

light_source {    // Illumination
  <-100,150,-120>
  color rgb 1
  }