reset
set term svg size 700,700 fname 'Verdana' fsize 12
set size square .9
set lmargin at screen .15
set tmargin at screen .9
set angles degrees
unset key
unset border
set polar
set rtics ("" 0, "0" 1, "1" 2, "2" 3, "3" 4, "4" 5, "5" 6, "6" 7)
set rrange [1e-2:7]
unset xtics
unset ytics
set grid polar 30 lt 1 lc 0 lw 0.3
 
set_label(x, text) = sprintf("set label '%s' at (8*cos(%f)), (8*sin(%f)) center", text, x, x)
 
eval set_label(0, "Methanol")        #6
eval set_label(30, "Aceton")         #0
eval set_label(60, "Acetonitril")    #0
eval set_label(90, "Dichlormethan")  #3
eval set_label(120, "Schwefelkohlenstoff") #6
eval set_label(150, "Toluol")        #6
eval set_label(180, "Diethylamin")   #3
eval set_label(210, "Tetrahydrofuran") #0
eval set_label(240, "Ethylacetat")   #0
eval set_label(270, "n-Heptan")      #6
eval set_label(300, "NaOH")          #6
eval set_label(330, "H2SO4")         #6
 
set output 'fluor.svg'
plot "-" u 1:2 t "Fluorkautschuk" w l lt 1 lw 3 lc rgb 0xFF0000
0 7
30 1
60 1
90 4
120 7
150 7
180 4
210 1
240 1
270 7
300 7
330 7
360 7
e
unset output