File:Tennis racket effect.gif
Summary
| Description |
English: Tennis racket effect: a 3D body has 3 principal axis of rotation. If they are all distinct and you try to rotate it around the axis with intermediate inertia, any small perturbation will get amplified and the rotation direction will "flip". |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1271457003337125890 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
| GIF development |
Mathematica 12.0 code
body = RegionUnion[Cylinder[{{0, 0, -0.1}, {0, 0, 0.1}}, 1], Cylinder[{{0.9, 0, 0}, {2, 0, 0}}, 0.15]];
inertia = MomentOfInertia[body];
I1 = inertia[[1, 1]]; I2 = inertia[[2, 2]]; I3 = inertia[[3, 3]];
eeq1 = FullSimplify[I1 \[Omega]x'[t] + \[Omega]y[t] \[Omega]z[t] (I2 - I3)];
eeq2 = FullSimplify[I2 \[Omega]y'[t] + \[Omega]x[t] \[Omega]z[t] (I3 - I1)];
eeq3 = FullSimplify[I3 \[Omega]z'[t] + \[Omega]x[t] \[Omega]y[t] (I1 - I2)];
sol = NDSolve[{eeq1 == 0, eeq2 == 0, eeq3 == 0, \[Omega]x[0] == 0, \[Omega]y[0] == 1, \[Omega]z[0] == 0.001}, {\[Omega]x, \[Omega]y, \[Omega]z}, {t, 0, 60}];
cm = Chop@RegionCentroid@body;
dt = 0.1;
rot = IdentityMatrix[3];
rotation = Reap[For[t = 0, t <= 60, t = t + dt,
axrot = Evaluate[{\[Omega]x[t], \[Omega]y[t], \[Omega]z[t]} /. sol][[1]];
rot = RotationMatrix[dt*Norm[axrot], axrot].rot;
Sow[Show[
Graphics3D[{
Dashed, Thick, Line[{-{0, 2, 0}, +{0, 2, 0}}]
}, Boxed -> False, ViewVector -> {3 {1, 1, 1}, {0, 0, 0}}, ViewAngle -> 50*Degree],
MapAt[GeometricTransformation[#, rot] &,
Show[
Graphics3D[{
Yellow,
Translate[Cylinder[{{0, 0, -0.1}, {0, 0, 0.1}}, 1], -cm],
Translate[Cylinder[{{0.9, 0, 0}, {2, 0, 0}}, 0.15], -cm]},
Boxed -> False, ViewVector -> {3 {1, 1, 1}, {0, 0, 0}}, ViewAngle -> 50*Degree]
], {1}]
]
];
];][[2, 1]];
ListAnimate[rotation]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
