File:Mushroomcloud Size.svg
Summary
| Description |
English: Final height h and radius r of a nuclear mushroom cloud as a function of the explosive yield W. The final height is approximately the height above the burst point for low and intermediate W and approx. the height above sea leval for high W.
Quelle: Glasstone & Dolan (1977), numerical approximation of original graph.
Deutsch: Endhöhe und Radius der Pilzwolke einer Kernwaffenexplosion als Funktion der Sprengkraft W. Die Endhöhe ist ungefähr die Höhe über dem Detonationspunkt für geringe und mittlere W und ungefähr die Höhe über Meeresniveau für große W.
Quelle: Glasstone & Dolan (1977), numerische Näherung des Originalgraphen. |
| Date | |
| Source | Own work |
| Author | SiriusB |
| Other versions | Mushroomcloud Size.png |
| SVG development | Category:Valid SVG created with Gnuplot#Mushroomcloud%20Size.svg  Category:Translation possible - SVGThis plot uses embedded text that can be easily translated using a text editor. |
The graph can be reproduced with Gnuplot (version 4.2 or higher) using this script
Source code
Gnuplot code
reset
lw1=2.0; lw2=2.0; lw3=1.; lw4=0.5
set term svg enhanced size 600,450 font "Helvetica, 14";set output 'cloud.svg'
ch=3.0 # scaling factor for height
cw=0.6 # scaling factor for radius
f(lx)=0.006941*lx**4-0.06216*lx**3+0.1526*lx**2+0.1878*lx # log height
g(lx)=0.0137*lx**3-0.0358*lx**2+0.37*lx # log radius
h(lx)=ch*10.**f(lx)
r(lx)=cw*10.**g(lx)
h0(lx)=ch*10.**(lx/3.)
r0(lx)=cw*10.**(lx/3.)
clx=0.75;dlx=0.2 # smooth interpolation via Fermi-Dirac function
tau(lx)=1./(exp((clx-lx)/dlx)+1.) # (other interpolations are possible)
uat(lx)=1.-tau(lx)
hsw(lx) = tau(lx)*h(lx)+uat(lx)*h0(lx)
rsw(lx) = tau(lx)*r(lx)+uat(lx)*r0(lx)
set logscale x; set logscale x2
set xrange [1:50000]; set xtics 10; set mxtics 10
set yrange [0:50]; set ytics 10; set mytics 5
set grid xtics ytics mxtics mytics back lt 1 lw 0.5 lc rgb '#808080',lt 1 lw 0.5 lc rgb '#B0B0B0'
set key left
## Use slanted fonts for variables if available
#set xlabel '{/Oblique W} / kT'; set ylabel '{/Oblique h},{/Oblique r} / km'
set xlabel 'W / kT'; set ylabel 'h, r / km'
plot hsw(log10(x)) t '{/Oblique h}' w l lt 1 lw lw1 lc rgb '#700', \
rsw(log10(x)) t '{/Oblique r}' w l lt 2 lw lw1 lc rgb '#F00'
reset
Licensing
 |
I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law. |
