File:Multiple scattering interference.gif
Summary
| Description |
English: A single point scatterer illuminated by a plane wave will produce a spherical wave, but if you increase the number of scatterers the interference between the scattered waves will quickly produce an apparently random speckle pattern. |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1128594815640379398 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 11.0 code
\[Lambda] = 1;
k0 = (2 \[Pi])/\[Lambda];
\[Alpha] = 4/(k0^2 I);
\[Sigma] = (k0^3 Norm[\[Alpha]]^2)/4 // N;
G[r_] := N[I/4 HankelH1[0, k0 Norm[r] ]];
source[x_] := E^(I k0 x); (*Plane wave illuminating the scatterers*)
p0 = GraphicsRow[{
DensityPlot[Re[source[x] ], {x, -10, 10}, {y, -10, 10}, PlotPoints -> 50, Frame -> False, PlotLabel -> "Re[E]", LabelStyle -> {Black, Bold}],
DensityPlot[Abs[source[x]]^2, {x, -10, 10}, {y, -10, 10}, PlotPoints -> 50, ColorFunction -> "AvocadoColors", PlotRange -> {0, 1}, Frame -> False, PlotLabel -> "|E\!\(\*SuperscriptBox[\(|\), \(2\)]\)",
LabelStyle -> {Black, Bold}]
}, ImageSize -> Large];
scatterers = {{0, 0}};
plots = Reap[Do[
dim = Dimensions[scatterers][[1]];
E0 = Table[N[source[scatterers[[j, 1]] ]], {j, 1, dim}] ;(*source field on each scatterer*)
iME = Inverse@Table[If[k == j, 1, \[Alpha] k0^2 G[scatterers[[j]] - scatterers[[k]] ] ], {j, 1, dim}, {k, 1, dim}];
Es = iME.E0 ;(*Total field on each scatterer*)
Etot = source[x] + \[Alpha] k0^2 Sum[Es[[j]]*G[{x, y} - scatterers[[j]]], {j, 1, dim}];
Sow@GraphicsRow[{
DensityPlot[Re[Etot ], {x, -10, 10}, {y, -10, 10}, PlotPoints -> 50, Epilog -> {Black, PointSize[0.02], Point[scatterers]}, Frame -> False, PlotLabel -> "Re[E]", LabelStyle -> {Black, Bold}]
,
DensityPlot[Abs[Etot ]^2, {x, -10, 10}, {y, -10, 10}, PlotPoints -> 50, ColorFunction -> "AvocadoColors", PlotRange -> {0, 5}, Epilog -> {White, PointSize[0.02], Point[scatterers]}, Frame -> False,
PlotLabel -> "|E\!\(\*SuperscriptBox[\(|\), \(2\)]\)", LabelStyle -> {Black, Bold}]
}, ImageSize -> Large];
AppendTo[scatterers, RandomReal[{-7, 7}, 2]];
, 20];][[2, 1]];
ListAnimate[plots]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
  |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
