Summary

DescriptionEpitrochoid512.svg	Epitrochoid made with gnuplot (see code below) whose parametric equations are: ${\displaystyle x=(R+r)\cos \theta -d\cos \left({R+r \over r}\theta \right),\,}$ ${\displaystyle y=(R+r)\sin \theta -d\sin \left({R+r \over r}\theta \right).\,}$ where ${\displaystyle R=5}$, ${\displaystyle r=1}$, ${\displaystyle d=2}$.
Date	26 January 2008
Source	Own work
Author	Ote

Gnuplot code

R=5.0
r=1.0
d=2.0
a=pi/4
set size ratio -1
set nokey
set nox2tics
set noy2tics
set zeroaxis lt -1
set grid
set noborder
set style line 1 linecolor 3 linewidth 3
set style line 2 linecolor -1 linewidth 3
set style line 3 linecolor 1 linewidth 3
set style line 4 linecolor 1 linewidth 5 pointtype 0 
set style line 5 linecolor -1 linewidth 5 pointtype 0 
set style line 6 linecolor -1 linewidth 1
set arrow from (R+r)*cos(a),(R+r)*sin(a) to (R+r)*cos(a) - d*cos((R+r)*a/r),(R+r)*sin(a) - d*sin((R+r)*a/r) nohead ls 6
set parametric
set samples 300
x1(t)=R*cos(t)
y1(t)=R*sin(t)
x2(t)=(R+r)*cos(a)+r*cos(t)
y2(t)=(R+r)*sin(a)+r*sin(t)
x3(t)=(R+r)*cos(t) - d*cos((R+r)*t/r)
y3(t)=(R+r)*sin(t) - d*sin((R+r)*t/r)
plot x1(t),y1(t) ls 1, x2(t),y2(t) ls 2, x3(t),y3(t) ls 3, '-' using ((R+r)*cos(a) - d*cos((R+r)*a/r)):((R+r)*sin(a) - d*sin((R+r)*a/r)) ls 4, '-' using ((R+r)*cos(a)):((R+r)*sin(a)) ls 5
0	0
e
0	0
e

Licensing

I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.