File:Iimj 5.png
Summary
| Description |
English: Uneven distribution of points ( nonuniformity) of inverse orbit of repelling fixed point of complex quadratic polynomial. Tips of Julia set are visited more frequently, then branch points. This method of drawing Julia set is called Inverse Iteration Method ( IIM ). Inverse iteration creates binary tree of preimages. Drawing repelling periodic point and it's orbit ( forward and backward= inverse) gives visually good aproximation of Julia set = set of points dense enough that nonuniform distribution of these points over Julia set is not important
Polski: Nierównomierna częstość występowania ( niejednolitość) punktów wstecznej orbity odpychającego punktu stałego. Końcowe punkty zbioru Julia są odwiedzane częściej, niż punkty w których zbiór się rozgałęzia. Ta metoda rysowania zbiory Julia nazywa się metodą wstecznej iteracji. Angielska nazwa : Inverse Iteration Method = IIM. Iteracja odwrotna tworzy binarne drzewo preobrazów, Rysowanie odpychającego punktu okresowego i jego orbity (do przodu i wstecz) daje wizualnie dobre przybliżenie zbioru Julii = zbiór punktów na tyle gęsty, że nierównomierny rozkład tych punktów na zbiorze Julii nie jest ważny. |
| Source | Own work |
| Author | Adam majewski |
Compare with
- Figure 27 on page 36 in Peitgen, Richter : The beauty of fractals. ISBN 0-387-15851-0
- Figure 3 on page 17 in Rational iteration: complex analytic dynamical systems by Norbert Steinmetz, Walter de Gruyter, 1993 , ISBN 3110137658,
Maxima src code
c:-1; /* define c value */
iMax:500000; /* maximal number of reversed iterations */
probability:0.5; /* one preimage is more contractive then other so it should be chosen .....*/
f(z,c):=expand(z*z+c);
finverseplus(z,c):=expand(sqrt(z-c));
finverseminus(z,c):=expand(-sqrt(z-c));
/* define z-plane ( dynamical ) */
zxMin:-2.0;
zxMax:2.0;
zyMin:-2.0;
zyMax:2.0;
/* define image size : width:iXmax-0+1; height:iYmax-0+1 ; */
iXmax:1000;
iYmax:1000;
/*
zx:zxMin+PixelWidth*iX ;
zy:zyMin+PixelHeight*iY;
so
iX:fix((zx-zxMin)/PixelWidth);
iY:fix((zy-zyMin)/PixelHeight);
*/
PixelWidth:(zxMax-zxMin)/iXmax;
PixelHeight:(zyMax-zyMin)/iYmax;
GiveJuliaPoints(c,iMax,probability):=
block(
xyv:[],
/* */
array(Hits,fixnum,iXmax,iYmax), /* 2D array of hits pixels . Hit > 0 means that point was in orbit */
fillarray (Hits,[0]), /* no hits for beginning */
/* compute fixed points of f(z,c) : z=f(z,c) */
fixed:float(rectform(solve([z*z+c=z],[z]))),
/* Find which is repelling */
if (abs(2*rhs(fixed[1]))<1)
then (
beta:rhs(fixed[1]),
alfa:rhs(fixed[2])
)
else (
alfa:rhs(fixed[1]),
beta:rhs(fixed[2])
),
/* choose repelling fixed point as a starting point of inversed iteration */
z:beta,
/* reversed iteration of beta */
for i:1 thru iMax step 1 do
(
if random(1.0)>probability
then z:finverseplus(z,c)
else z:finverseminus(z,c),
iX:fix((realpart(z)-zxMin)/PixelWidth),
iY:fix((imagpart(z)-zyMin)/PixelHeight),
/* save hits values to draw it later */
Hits[iX,iY]:Hits[iX,iY]+1
),
/* */
for iX:0 thru iXmax step 1 do
for iY:0 thru iYmax step 1 do
if (Hits[iX,iY]>0) then
(zx:zxMin+PixelWidth*iX ,
zy:zyMin+PixelHeight*iY,
xyv:cons([zx,zy,Hits[iX,iY]],xyv)),
return(xyv)
)$
JuliaPoints:GiveJuliaPoints(c,iMax,probability);
/* draw reversed orbit of beta using draw package */
load(draw);
draw3d(
file_name = "iimj_5",
terminal = 'screen,
pic_width = iXmax,
pic_height = iYmax,
yrange = [zyMin,zyMax],
xrange = [zxMin,zxMax],
title= concat("Julia set for c=",string(c)," using IIM (",string(iMax)," points, prob= 0.5)"),
xlabel = "Z.re ",
ylabel = "Z.im",
point_type = dot,
points_joined = impulses,
line_width = 2,
color = red,
point_size = 5,
/*color = black,*/
points(JuliaPoints)
);
Licensing
I, the copyright holder of this work, hereby publish it under the following licenses:
This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
 |
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License. |
You may select the license of your choice.