#-------------------------------------------------------------
# Script for gnuplot 4.6, Lizenz: CC-BY-SA-3.0 by Udo Brechtel
#-------------------------------------------------------------
reset
#-------------------------------------------------------------
# Variablendeklaration:
#-------------------------------------------------------------

#Canvas:
xsize = 1000
ysize = 600
xleftmargin = 10
ytopmargin  = 5

Jahr = 2014

conv = 1000

#Wertebereich:
zvEmin = 0; zvEmax = 120000; zvEstep = 5000

#x-/y-Achse (konvertiert):
xmin = zvEmin/conv; xmax = zvEmax/conv; dx = zvEstep/conv
ymin = 0;           ymax = 50;          dy = 5

#Legende Position:
xkey = 2; ykey = 48

#Diagrammtitel:
lblTITEL  = "Einkommensteuer Deutschland\n\nGrund- und Splittingtarif ".Jahr;
lblYACHSE = "Durchschnitt-/Grenzsteuersatz"
lblXACHSE = "Jährlich zu versteuerndes Einkommen (Euro)"

lblZUSATZINFO = "BGBl 2013 Teil I Nr. 9 S. 283, Änderung EStG § 32a Abs. 1"

fontterm        = "Arial, 10"
fonttitle       = "Arial Bold, 14"
fontxytics      = "Arial, 12"
fontxylabels    = "Arial Bold, 12"
fontkeylabels   = "Arial Bold, 11"
fontlabels      = "Arial, 6"

#----------------------------------------------------------------------------
# Settings
#----------------------------------------------------------------------------
set encoding iso_8859_1 

set noborder
set zeroaxis

set sample 1201

set terminal svg size xsize,ysize font fontterm dashed background rgb "white"
set lmargin xleftmargin
set tmargin ytopmargin

#Diagrammtitel
set title lblTITEL offset 15,0 font fonttitle

#Legende (key)
set label at -7,55 left "Grenzsteuersatz (gestrichelte Linie)\nSteuersatz (durchgezogene Linie)" font fontkeylabels

set key at xkey,ykey left Left spacing 1.5 width 1 height 1 box 0
set key opaque reverse   vertical maxrows 8
set key font fontkeylabels

#y-Achse
set yrange [ymin:ymax]
set format y "%.0f %%"
set ytics out nomirror ymin,dy font fontxytics
set ytics add ("0" 0)
set mytics dy
#set ylabel lblYACHSE offset -0.8,0 font fontxylabels
                              
#x-Achse
set xrange [xmin:xmax]
set format x "%g 000" #Tausendertrennung
set xtics out nomirror rotate xmin,dx font fontxytics
set mxtics dx
set xtics add ("0" 0)
set xlabel lblXACHSE offset (2*dx),-2.0 font fontxylabels

#Labels Info
set label at -7,-10 left lblZUSATZINFO font fontlabels

#Gitternetz
set grid xtics mxtics ytics mytics lw 0.6, lw 0.2

#-------------------------------------------------------------
# Einkommensteuertarif 2014:
#-------------------------------------------------------------
# Eckwerte zvE (obere Grenze):
 e(n) =   8354*(n==0) \
      +  13469*(n==1) \
      +  52881*(n==2) \
      + 250730*(n==3) 

# Welche Zone?
 n(zve) = 0*           (zve<=e(0)) \
        + 1*(zve>e(0))*(zve<=e(1)) \
        + 2*(zve>e(1))*(zve<=e(2)) \
        + 3*(zve>e(2))*(zve<=e(3)) \
        + 4*(zve>e(3))

# Eckwert zur Differenzbildung
 ea(n) =   e(0)*(n==1) \
       +   e(1)*(n==2)

# Linearer Progressionsfaktor:
 a(n) = 974.58e-8*(n==1) \
      + 228.74e-8*(n==2)

# Anfänglicher Grenzsteuersatz:
 b(n) = 0.1400*(n==1) \
      + 0.2397*(n==2) \
      + 0.42  *(n==3) \
      + 0.45  *(n==4) 

# y-Achsenabschnitt bzw. StB der unteren Zonen:
 c(n) =    971*(n==1) \
      +  -8239*(n==2) \
      + -15761*(n==3) 
#-------------------------------------------------------------
#Funktionen:
#-------------------------------------------------------------

# Abzuziehender Eckwert :
 ean(zve) = ea(n(zve))

 zve(x)  = x*conv
 dzve(x) = zve(x) - ean(zve(x))

# Massgebender linearer Progressionsfaktor
 an(zve) = a(n(zve))

# Massgebender Grenzsteuersatz
 bn(zve) = b(n(zve))

# Massgebender y-Achsenabschnitt bzw. StB der unteren Zonen:
 cn(zve) = c(n(zve)-1)


#Steuerbetrag
# -Grundtarif     (v==0)
# -Splittingtarif (v==1)
 Stb0(x) = ( an(zve(x))*dzve(x)**2 + bn(zve(x))*dzve(x) + cn(zve(x)) ) /conv
 Stb1(x) = 2*Stb0(x/2)
 Stb(x,v) = Stb0(x)*(v==0) + Stb1(x)*(v==1)

#Grenzsteuersatz
 sg0(x) = ( 2*an(zve(x))  *dzve(x)   + bn(zve(x))   ) * 100
 sg1(x) = ( 2*an(zve(x/2))*dzve(x/2) + bn(zve(x/2)) ) * 100
 sg(x,v) = sg0(x)*(v==0) + sg1(x)*(v==1)

#Durchschnittsteuersatz alle Zonen
 s(x,v) = Stb(x,v) * 100 / x

#-----------------------------------------------------------------

#Linienstyles sg
set style line 13000 lt 2 lw 1.0 lc rgb "blue"
set style line 13001 lt 2 lw 1.0 lc rgb "red"
#Linienstyles s
set style line 13010 lt 1 lw 1.2 lc rgb "blue"
set style line 13011 lt 1 lw 1.2 lc rgb "red"

#-----------------------------------------------------------------
#Ausgabedatei
fn = "ESt_D_Splitting_".Jahr."_zvE_bis_".zvEmax.".svg"

set output fn

plot sg(x,0) ls 13000 notitle, \
     sg(x,1) ls 13001 notitle, \
     s(x,0)  ls 13010 t "Grundtarif", \
     s(x,1)  ls 13011 t "Splittingtarif"

unset output