File:Beta distribution cdf.svg

Summary

Description
English: Cumulative distribution function for the Beta distribution. Based on work of Krishnavedala.
Date
Source Own work
Author Horas
Other versions
SVG development
InfoField

Licensing

This work is ineligible for copyright and therefore in the public domain because it consists entirely of information that is common property and contains no original authorship.
Category:PD ineligible#Beta%20distribution%20cdf.svg

Source Codes

Using gnuplot
reset
reset session

out=2
outputpath= "./"
outputfilename="betacummulative"
if(out==1) {
	set terminal qt size 1000,750 font ",14"
}
if(out==2) {
	set terminal pdfcairo size 16cm,12cm  font ",20" linewidth 2
	set output outputpath.outputfilename.".pdf"
}
if(out==3) {
	set terminal pngcairo size 800,600  font ",14"
	set output  outputpath.outputfilename.".png"
}

dbeta(x,a,b) = exp((a-1)*log(x)+(b-1)*log(1-x)-lgamma(a)-lgamma(b)+lgamma(a+b))
pbeta(x,a,b) = ibeta(a,b,x)
f(x,y,z) = pbeta(x,y,z)

set samples 500
 
set xrange [0:1]
set xtics 0.2
set yrange [0:1]
set ytics 0.2

#set xlabel "x"
set ylabel "CDF"

set key at .40,1

set grid xtics ytics mytics lw 1 lc rgb "#888" dashtype 3 lt 1
set border 3 back lw 2 lc rgb "#222"
set tics in nomirror scale 0.75

lww=2
set ls 1 lw lww lc rgb "#E41A1C"
set ls 2 lw lww lc rgb "#377EB8"
set ls 3 lw lww lc rgb "#4DAF4A"
set ls 4 lw lww lc rgb "#984EA3"
set ls 5 lw lww lc rgb "#FF7F00"

plot \
    f(x, 0.5,0.5) w l ls 1	title "{/Symbol a} = {/Symbol b} = 0.5", \
    f(x, 5,  1)   w l ls 2	title "{/Symbol a} = 5, {/Symbol b} = 1", \
    f(x, 1,  3)   w l ls 3	title "{/Symbol a} = 1, {/Symbol b} = 3", \
    f(x, 2,  2)   w l ls 4	title "{/Symbol a} = 2, {/Symbol b} = 2", \
    f(x, 2,  5)   w l ls 5	title "{/Symbol a} = 2, {/Symbol b} = 5"

if (out>1) {
	set output
}
if (out == 1) {
	pause -1
}
Using python with matplotlib, scipy and numpy toolboxes.
from matplotlib.pyplot import *
from numpy import linspace
from scipy.stats import beta

x = linspace(0,1,75)

fig = figure()
ax = fig.add_subplot(111)
ax.plot(x,beta.cdf(x,0.5,0.5),label=r"$\alpha=\beta=0.5$")
ax.plot(x,beta.cdf(x,5,1),label=r"$\alpha=5, \beta=1$")
ax.plot(x,beta.cdf(x,1,3),label=r"$\alpha=1, \beta=3$")
ax.plot(x,beta.cdf(x,2,2),label=r"$\alpha=2, \beta=2$")
ax.plot(x,beta.cdf(x,2,5),label=r"$\alpha=2, \beta=5$")
ax.grid(True)
ax.minorticks_on()
ax.legend(loc=9)
setp(ax.get_legend().get_texts(),fontsize='small')
ax.set_ylim(0,2.6)
ax.set_xlabel("x")
ax.set_ylabel("PDF")

fig.savefig("Beta_distribution_cdf.svg",bbox_inches="tight",\
	pad_inches=.15)
Category:Beta distribution Category:Images with Gnuplot source code Category:Images with Python source code Category:SVG created with Matplotlib
Category:Beta distribution Category:Images with Gnuplot source code Category:Images with Python source code Category:PD ineligible Category:SVG created with Matplotlib Category:Valid SVG created with Gnuplot:Symbols