#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['01.01.1945':'31.12.1989']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 5
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5          # Unterteilung der Skalierung
set xtics nomirror    # Nur unten Skalieren
set format x '%Y'     # Beschriftungsformat JJJJ


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [100000:]
set ytics 10000
set mytics 5
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f" # Ausgabeformat


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot 'Einwohnerentwicklung_von_Hagen.dat' \
  using 1:($2) with filledcurves below x1 lt rgb 'dark-blue' lw 2